Beschriftung von Balkendiagrammen – Intervallgrenzen statt Intervallmittelpunkte

Aus SAS-Wiki
Wechseln zu: Navigation, Suche

Von Carina Ortseifen: Hans-Peter Altenburg, Heinrich Stürzl, Almut Hahn, Carina Ortseifen, Grischa Pfister: Tipps und Tricks für den leichteren Umgang mit der SAS Software, KSFE 2008

Im folgenden Tipp sollen verschiedene Möglichkeiten aufgezeigt werden, wie die Balkenachse bei mit der Prozedur Gchart im SAS System erzeugten Balkendiagramme beschriftet werden können. Dabei spielt es keine Rolle, ob die Anweisung Vbar oder Hbar verwendet wird. Als Beispieldatei dient die Variable Height aus der SAS-Tabelle sashelp.class.

Balkendiagramm.JPG

Mit dem Standardaufruf der Prozedur Gchart erhält man folgendes Diagramm:

Proc Gchart 
   Data=sashelp.class;
   Vbar height;
Run;Quit;

Auf der vertikalen Achse links werden die Häufigkeiten (Frequency) ausgegeben, die horizontale Achse trägt die Balken. Dafür ermittelt das SAS System nach einem intern implementierten Algorithmus die Intervallgrenzen und –mittelpunkte und gibt diese “Midpoints” auf der Achse aus (Height Midpoint).

Mit der Option Levels= kann die Zahl der Balken vom Anwender bestimmt werden. In unserem Beispiel sollen drei Balken angezeigt werden.

Proc Gchart 
   Data=sashelp.class;
   Vbar height / 
     Levels=3;
Run;Quit;
Balkendiagramm2.JPG

Ergänzt man die Syntax zusätzlich mit der Option Range, werden statt der Mittelpunkte die Intervallgrenzen der Balkendiagramme angezeigt:

Proc Gchart 
   Data=sashelp.class;
   Vbar height / 
     Levels=3
     Range;
Run;Quit;
Balkendiagramm3.JPG

Die Balken umfassen dabei die halboffenen Intervalle, z.B. 55<65. Bei den beiden Balken am Rand wird als Grenze <55 bzw. >=65 angegeben.

Die Option Range kann auch mit Midpoints= kombiniert werden, wenn man feste Grenzen vorgeben möchte:

Proc Gchart
   Data=sashelp.class;
   Vbar height / 
     Midpoints=55 65 75
     Range;
Run;Quit;
Balkendiagramm4.JPG


Um die Mittelpunkte 55, 65 und 75 werden nun die Intervallgrenzen angelegt, die Balken ent¬sprechend eingezeichnet und die Intervall¬grenzen angezeigt.

Jetzt bleibt nur noch ein Wunsch übrig: Nach unten halboffene Intervallgrenzen. Dafür muss zunächst ein Format definiert werden, das dann im Prozedur Gchart-Schritt der Variable height zugewiesen wird:

Proc Format;
   Value hoehe Low-60 = "< 60„
               60<-70 = "60-70„
		   70<-High = "> 70";
Run;
Proc Gchart Data=sashelp.class;
   Vbar height / Discrete;
   Format height hoehe.;
Run;Quit;

Balkendiagramm5.JPG

Zusammenfassung

Per Default werden die Balkenmittelpunkte bei Anwendung der Prozedur Gchart mit Anweisung Vbar/Hbar angezeigt. Einfluss auf Anzahl und Lage der Balken bieten die Optionen Midpoints= und Levels=. Mit der Option Range können alternativ die Balkengrenzen dargestellt werden. Der Einsatz von Formaten bietet darüber hinaus weitere Möglichkeiten.

Literatur

  • Altenburg et al.: Tipps und Tricks für den leichteren Umgang mit der SAS Software

Proceedingsband der 11. KSFE 2007 Ulm. Shaker Verlag, 2007.